// PoVRay 3.6 Scene File "HexPen.pov"
// author:  Florian Simon
// date:    2011/11/15

#version 3.6;
global_settings{ assumed_gamma 1.0 }
//---------------------------------------
#include "shapes_lo.inc"   
#include "HexPen.inc" 
#include "Clock_Splitting.inc"
//---------------------------------------
camera{ angle 45
        right x*image_width/image_height
        location <-1.5 , 2 ,-5.0>*0.9
        look_at  <-0.2 , -0.5 , 0>}
//---------------------------------------
light_source{ <1500,2500,-2500>
              color rgb<1,1,1> }
//---------------------------------------
sky_sphere{ pigment{color rgb<1,1,1>}}
//---------------------------------------

 




//  textures-----------------------------------
#declare Edge_Texture =
texture{ pigment{ color rgb< 0.75, 1.0, 0.0>*0.8 } //  yellow lemon        //
         finish { phong 1 }
       } // end of texture
#declare Corner_Texture =
texture{ pigment{ color rgb< 0.35, 0.6, 0.0> } // yellow lemon darker      // Textures of multicolour Hexagon
         finish { phong 1 }
       } // end of texture
#declare Face_Texture =
texture{ pigment{ color rgb< 0.95, 1.0, 0.4>*1.1} // yellow lemon pale     //
         finish { phong 0.1 }
       } // end of texture    
#declare P_Texture =
texture{ pigment{ color rgb< 0.95, 0.1, 0.0> transmit 1-Sclock_01(7,8)} // changing color
         finish { phong 0.1 } 
       } // end of texture     
#declare H_Texture =
texture{ pigment{ color rgb< 0.35, 0.8, 0.0> transmit 1-0.75*Sclock_01(8,8)} // changing color
         finish { phong 0.1 } 
       } // end of texture
#declare P_Texture_F =
texture{ pigment{ color rgb< 0.95, 0.1, 0.0> } // changing color
         finish { phong 0.1 } 
       } // end of texture     
#declare H_Texture_F =
texture{ pigment{ color rgb< 0.35, 0.8, 0.0> } // changing color
         finish { phong 0.1 } 
       } // end of texture                    
#declare PM_Texture =
texture{ pigment{ color rgb< 0.35, 0.8, 0.0> transmit 1-Sclock_01(3,8)} // changing color
         finish { phong 0.1 } 
       } // end of texture
#declare PMV_Texture =
texture{ pigment{ color rgb< 0.35, 0.8, 0.0> transmit Sclock_01(5,8)} // changing color
         finish { phong 0.1 } 
       } // end of texture
#declare HM_Texture =
texture{ pigment{ color rgb< 0.90, 0.9, 0.4> transmit 1-Sclock_01(1,8)} // changing color
         finish { phong 0.1 } 
       } // end of texture
#declare HMV_Texture =
texture{ pigment{ color rgb< 0.9, 0.9, 0.4> transmit Sclock_01(2,8)} // changing color
         finish { phong 0.1 } 
       } // end of texture


//  end of textures ---------------------------------- 



// angles ------------------------------------------
#declare HHAng=(360/(2*pi))*acos((-1/3)*(sqrt(5))) ;              // Angle between Hexagon and Hexagon  (faces)
#declare HPAng=(360/(2*pi))*acos(-(sqrt((5+2*sqrt(5))/(15)))) ;   // Angle between Pentagon and Hexagon (faces)
#declare HHAng_1=0.5*(180-HHAng) ;                                
#declare HPAng_1=0.5*(180-HPAng) ;                                
// ------------------------------------- 










//-------------------------------------------------------
//--------------OBJECTS----------------------------------
//-------------------------------------------------------

#declare Total=8 ;
#declare StepNr=1 ; 

#if (clock<StepNr/Total) //1
  union {
     object{ HexHex(1,1,180) }
     object{ Hex_C(1,1) rotate<0,0,0> texture{ HM_Texture } }   
        }    
        
#else
 #declare StepNr = StepNr +1 ;

#if (clock<StepNr/Total) //2
  union {
     object{ HexHex(1,1,180) }
     object{ Hex_C(1,1) rotate<0,0,0> texture{ HMV_Texture } }   
        }    
        
#else
 #declare StepNr = StepNr +1 ;

#if (clock<StepNr/Total) //3
  union {
     object{ HexHex(1,1,180) }
     object{ Pen_C(1,1) texture{ PM_Texture } }   
        }    
        
#else
 #declare StepNr = StepNr +1 ;

#if (clock<StepNr/Total) //4
  union {
     object{ HexHex(1,1,180) }
     object{ Pen_C(1,1) texture{ H_Texture_F } rotate <0,sin(Sclock_01(StepNr,Total)*2*pi)*6,0> }   
        }
 
#else
 #declare StepNr = StepNr +1 ;

#if (clock<StepNr/Total) //5
  union {
     object{ HexHex(1,1,180) }
     object{ Pen_C(1,1) texture{ PMV_Texture } }   
        }    

#else
 #declare StepNr = StepNr +1 ;


#if (clock<StepNr/Total) //6
  object{ HexHex(1,1,180-Sclock_01s(StepNr,Total)*HHAng_1*2) rotate<0,0,Sclock_01s(StepNr,Total)*HHAng_1>  }

#else
 #declare StepNr = StepNr +1 ;

#if (clock<StepNr/Total) //7
  union {
     object{ HexHex(1,1,HHAng) rotate<0,0,HHAng_1>  }
     object{ Pen_C(1,1) 
        texture{P_Texture }
        rotate<0,-36,0> rotate<-HPAng_1*2,0,0> rotate<0,30,0> rotate<0,0,-HHAng_1> }
        }       
#else                    //8
 #declare StepNr = StepNr +1 ;
  union {  
    object{ HexHex(1,1,HHAng) rotate<0,0,HHAng_1>  }
    object{ Pen_C(1,1) 
        texture{P_Texture_F}
        rotate<0,-36,0> rotate<-HPAng_1*2,0,0> rotate<0,30,0> rotate<0,0,-HHAng_1> }    
    object{ HexHex_C(1,1,180) texture{H_Texture } } 
        }
#end        
#end
#end
#end
#end  
#end
#end